课程设计can总线数据通信系统的设计.doc

太原科技大学课程设计论文

CAN总线数据通信系统的设计

摘 要
现场总线是当今自动化领域技术发展的热点之一，被誉为自动化领域的计算机局域网。它的出现为分布式控制系统实现各节点之间实时、可靠的数据通信提供了强有力的技术支持。CAN(Controller Area Network)属于现场总线的范畴，是一种多主方式的串行通讯总线，数据通信实时性强。与其它现场总线比较而言，CAN总线具有通信速率高、容易实现、可靠性高、性价比高等诸多特点。
本系统要在单片机中实现CAN总线的接口，通过CAN总线，实现两个模块之间的数据通讯。系统主要由四部分所构成：PC机、微控制器80C51、独立CAN通信控制器SJA1000和CAN总线收发器PCA82C250。微处理器80C51负责SJA1000的初始化，通过控制SJA1000实现数据的发送和接收等通信任务。CAN总线节点的软件设计主要包括三大部分：CAN节点初始化、报文发送和报文接收。
本系统通过扩展CAN总线控制器SJA1000，在单片机系统中实现了CAN总线的接口，并且编写了SJA1000的驱动程序，通过读写其的内部寄存器，完成工作方式的设置、接收滤波方式的设置、接收屏蔽寄存器（AMR）和接收代码寄存器（ACR）的设置、波特率参数设置和中断允许寄存器（IER）的设置等基本操作；利用各基本操作，完成了对SJA1000的初始化，并且实现了数据发送和接收。
太原科技大学课程设计论文
目 录
第1章 原理与方案 1
1.1 设计目的与要求 1
1.2 CAN总线介绍 1
1.3 设计方案 2
1.3.1 硬件设计方案 2
1.3.2 软件设计方案 4
第2章 硬件连接与说明 5
2.1 硬件连接 5
2.1.1 模块使用说明 6
2.1.2 实验箱连线 6
2.2 CAN总线控制器SJA1000 6
2.3 CAN控制器接口PCA82C250 7
第3章 软件流程图及说明 8
3.1 软件流程图 8
3.1.1 主程序流程图 8
3.1.2 初始化子程序流程图 8
3.1.3 发送数据子程序流程图 10
3.1.4 接收数据子程序流程图 10
3.2 软件实现过程 10
第4章 结果分析及心得体会 12
4.1 结果分析 12
4.2 心得体会 13
4.2.1 CAN应用中的问题 14
4.2.2 CAN总线的其他应用 14
附录 程序清单 15
参考文献 23

II

第1章 原理与方案
1.1 设计目的与要求
扩展CAN总线控制器，在单片机系统中实现CAN总线的接口，并编写接口芯片的驱动程序。通过CAN总线，实现两个模块之间的数据通讯，CPU控制第一个模块发送1帧数据，第二个模块收到这帧数据并送至另一个CPU的内部存储器。
1.2 CAN总线介绍
CAN全称为“Controller Area Network”， 即控制器局域网，是国际上应用最广泛的现场总线之一。最初CAN被设计作为汽车环境中的微控制器通讯，在车载各电子控制装置ECU之间交换信息，形成汽车电子控制网络。比如发动机管理、系统变速箱控制器、仪表装备中，均嵌入CAN控制装置。
一个由CAN总线构成的单一网络中，理论上可以挂接无数个节点。实际应用中，节点数目受网络硬件的电气特性所限制。例如当使用Philips PCA82C250作为CAN收发器时，同一网络中允许挂接110个节点。CAN 可提供高达1Mbit/s的数据传输速率，这使实时控制变得非常容易，另外硬件的错误检定特性也增强了CAN的抗电磁干扰能力。
CAN是一种多主方式的串行通讯总线。基本设计规范要求有高的位速率，高抗电磁干扰性，而且能够检测出产生的任何错误。当信号传输距离达到10Km 时，CAN仍可提供高达50Kbit/s 的数据传输速率。由于CAN 总线具有很高的实时性能，因此CAN已经在汽车工业、航空工业、工业控制、安全防护等领域中得到了广泛应用。
1.3 设计方案
在本系统中，采用80C51单片机，80C51与PC机串行通信，设置SJA1000工作于Intel模式，由PC机发送的数据写入SJA1000并通过CAN收发器发送。接收数据是通过中断进行的，CAN 总线传输过来的数据经CAN接口芯片PCA82C250接收并写入SJA1000的RXFIFO，然后通过中断提请CPU读取，读取的数据上传送给PC机。

总体设计框图如图1-2所示。

图1-2 总体设计框图
1.3.1 硬件设计方案
1. 芯片介绍
SJA1000：独立式CAN控制器，具有64字节的FIFO作为接收缓存。
6N137：高速光隔，最高速度10Mb／s，用于保护CAN控制器。
PCA82C250：CAN总线收发器，是CAN控制器与CAN总线的接口器件，对CAN总线差分式发送。
2. CAN控制器与CPU接口设计
对于CPU来说，CAN控制器是确保双方独立工作的存贮器映象外围设
备。CAN控制器与外部CPU的接口是通过控制器接口逻辑（CIL）实现的，80C51 的CPU通过将地址总线（AB）和数据总线（DB）连接到CIL上来完成与CAN控制器之间的信息交换,不需要专门的控制总线（CB），CPU与PCA82C250之间的状态、控制和命令信号的交换在CAN控制器中完成。
SJA1000与单片机的接口电路如图1-3所示。

图1-3 SJA1000与单片机的接口电路
3. CAN控制器工作电路的连接
为了增强CAN总线节点的抗干扰能力，SJA1000的TX0和RX0并不是直接与PCA82C250的TXD和RXD相连，而是通过高速光隔6N137后与PCA82C250相连，这样就很好的实现了总线上各CAN节点间的电气隔离。
若PCA82C250处于CAN总线的网络终端，总线接口部分需加一个120欧姆的匹配电阻。

CAN控制器工作电路如下图所示:

图1-4 CAN控制器工作电路
1.3.2 软件设计方案
CAN 总线节点的软件设计主要包括三大部分：CAN节点初始化、报文发送和报文接收。熟悉这三部分程序的设计就能编写出利用CAN总线进行通信的一般应用程序。当然要将CAN总线应用于通信任务比较复杂的系统中，还需详细了解有关CAN总线错误处理、总线脱离处理、接收滤波处理、波特率参数设置和自动检测以及CAN总线通信距离和节点数的计算等方面的内容。
SJA1000的初始化只有在复位模式下才可以进行，初始化主要包括工作方式的设置、接收滤波方式的设置、接收屏蔽寄存器（AMR）和接收代码寄存器（ACR）的设置、波特率参数设置和中断允许寄存器（IER）的设置等。在完成SJA1000的初始化设置以后，SJA1000就可以回到工作状态，进行正常的通信任务。
发送子程序负责节点报文的发送。发送时用户只需将待发送的数据按特定格式组合成一帧报文，送入SJA1000发送缓存区中，然后启动SJA1000 发送即可。
接收子程序负责节点报文的接收以及其它情况处理。接收子程序比发送子程序要复杂一些，因为在处理接收报文的过程中，同时要对诸如总线脱离、错误报警、接收溢出等情况进行处理。SJA1000报文的接收主要有两种方式：中断接收方式和查询接收方式，两种接收方式编程的思路基本相同，如果对通信的实时性要求不是很强，一般采用查询接收方式。
第2章 硬件连接与说明
2.1 硬件连接
单片机与CAN模块等外围器件的连接如图2-1所示。

图2-1 系统原理图
2.1.1 模块使用说明
CAN总线模块由一个CAN总线控制器SJA1000和一个CAN收发器PCA82C250组成,它们共同构成一个CAN节点。模块的电源由接口挂箱上的接口插座提供。
模块上的RESET、INT、TX0、RX0插孔分别对应于SJA1000芯片上的相应引脚。模块上带有上电复位电路，也可通过RESET插孔进行手动复位，只需在RESET上加上负脉冲。
模块上提供两个RJ45接口和一组“CANH、CANL”插孔接口，这三组接口是完全一致的。对于近距离CAN模块之间的通讯，可将各模块的“CANH、CANL”插孔用导线连接；对于远距离CAN模块之间的通讯，则可用双绞线连接各RJ45接口。
每个CAN模块上都有一组终端电阻接口，即“A、B”插孔。当总线上只有两个CAN节点时，终端电阻可不接。如总线上的CAN节点数为3个或3个以上时，必须有一个而且只能有一个CAN模块接上终端电阻。具体接法为：将A插孔和CANL插孔、B插孔和CANH插孔分别用导线连接。
2.1.2 实验箱连线
两个CAN模块分别接在两个实验台上，第一个模块（发送）跳线接LCS2,第二个模块（接收）跳线接LCS3，用双绞线连接两个模块的RJ45接口，将第一个CAN模块接上终端电阻。
2.2 CAN总线控制器SJA1000
SJA1000是一种独立的CAN控制器，主要用于移动目标和一般工业环境中的区域网络控制。它是Philips半导体公司PCA82C200 CAN控制器（BasicCAN）的替代产品，增加了一种新的操作模式——PeliCAN，这种模式支持具有很多新特性的CAN2.0B协议。
2.3 CAN控制器接口PCA82C250
PCA82C250是CAN协议控制器和物理总线间的接口，它主要是为汽车中高速通讯（高达1Mbps）应用而设计。此器件对总线提供差动发送能力，对CAN控制器提供差动接收能力，与ISO11898标准完全兼容。
PCA82C250芯片由接收器、驱动器、基准电压产生电路、工作模式选择电路及保护电路等组成。PCA82C250内部的限流电路可以防止发送输出级对电池电压的正端和负端短路。虽然在这种故障条件出现时，功耗将增加，但这种特性可以阻止发送器输出级的破坏。

在节点温度大约超过160℃时，两个发送器输出端的极限电流将减少。由于发送器是功耗的主要部分，因此芯片温度会迅速降低。PCA82C50芯片的其他部分将继续工作。当总线短路时，热保护十分重要。
CANH和CANL两条线也可以防止在汽车环境下可能发生的电气瞬变现象。

第3章 软件流程图及说明
3.1 软件流程图
3.1.1 主程序流程图
程序开始运行后，先调用初始化子程序，分别对两个CAN模块中的SJA1000进行初始化，然后把要发送的数据写入CPU的存储器中，然后循环调用发送数据子程序和接收数据子程序。具体流程如图3-1所示。

图3-1 主程序流程图
3.1.2 初始化子程序流程图
初始化子程序先设置MOD选择复位模式，然后分别设置CDR选择工作模式；设置IER选择中断类型；设置BTR0、BTR1设定传输速率；设置OCR选择输出模式；设置ACR、AMR设定接收数据类型；RBSA、TXERR、ECC均清零，最后设置MOD进入工作模式。具体流程如图3-2所示。

图3-2 初始化子程序流程图

3.1.3 发送数据子程序流程图
发送数据子程序先把三个控制字节写入发送缓冲区，然后把等待发送的数据也写入发送缓冲区，最后设置CMR，发出发送请求、启动SJA1000发送数据。具体流程如图3-3所示。

图3-3 发送数据子程序流程图
3.1.4 接收数据子程序流程图
接收数据子程序首先要读SR和IR，判断工作状态及中断类型并做相应处理，若RXFIFO有数据，应判断帧类型并做相应处理，若数据正确则送至CPU的内部存储器。具体流程如图3-4所示。
3.2 软件实现过程
两个实验台运行程序CAN.ASM（程序见附录），发送实验台全速运行程序，接收实验台要在主程序中调用接收数据子程序后设置断点，等待接收到数据后送至CPU的存储器，然后查看CPU的内部存储器30H~37H中的数据与程序中发送的数据是否一致。

图3-4 接收数据子程序流程图
第4章 结果分析及心得体会
4.1 结果分析
本试验通过扩展CAN总线控制器，在单片机系统中实现了CAN总线的接口，通过CAN总线，实现了两个模块之间的数据通讯，在第一个模块中发送1帧数据，在第二个模块中收到这帧数据并送至了CPU的内部存储器30H~37H。
如果要修改发送数据，只需修改程序中“TXDATA”后8个字节的数据即可。
发送实验台内部存储器如图4-1所示。

图4-1 发送实验台

接收实验台内部存储器如图4-2所示。

图4-2 接收实验台
4.2 心得体会
通过本次设计对CAN总线的工作原理及其与CPU的接口方式有了一定程度的理解。基于CAN总线可实现多种数据的传输，例如：可将文字、图像等进行编码后传输，并在接收端进行解码后恢复，由于时间有限未做深入研究。
开发CAN总线控制节点时，还可以使用集成了CAN控制器的CPU 80C592，但支持80C592的开发工具少，给开发工作带来一定的难度。所以一般使用独立的CAN 控制器SJA1000配合单片机进行开发。

4.2.1 CAN应用中的问题
SJA1000有BasicCAN和PeliCAN两种工作模式，SJAl000上电复位后自动进入BasicCAN，因此选用PeliCAN模式必须在程序中设置时钟分频寄存器（CDR）选择工作模式。
总线定时寄存器的设置极大影响了CAN性能的发挥。一般来说，若硬件连接无误，通信失败的主要原因在于总线定时寄存器设置不当。在实验中，曾出现过因SJA1000的时钟电路中晶振严重漂移导致通信失败的情况。
ACR和AMR两个寄存器构成硬件过滤，CAN节点通过它来决定是否接收总线上的数据，是否置CAN的接收中断，这极大地提高了系统的灵活性。
可以通过中断寄存器（IR）、状态寄存器（SR）查询CAN总线的工作状态，了解数据传输状况。为了保证数据的正常收发，需要对状态寄存器和中断寄存器各状态位的变化做出相应处理。
4.2.2 CAN总线的其他应用
CAN（Controller Area Network）总线最早由德国BOSCH公司提出，主要用于汽车内部测量与控制中心之间的数据通信。由于其良好的性能，在世界范围内广泛应用于其他领域当中，如工业自动化、汽车电子、楼宇建筑、电梯网络、电力通讯和安防消防等诸多领域，并逐渐成为这些行业的主要通讯手段。
一个由CAN总线构成的单一网络中，可以挂接多个节点，实际应用中只需要设置几个节点为上位节点与PC机进行通信，其他节点则可以做其他用途。如用于数据的采集，则与A/D转换芯片相接即可；如与控制相关，则与控制口相接即可，这样一来可以灵活地构成各种系统。
CAN总线具有多方面的优势，可以组建一个具有高可靠性、远距离、多节点、多主方式的设备通讯网络，例如：我国许多煤矿中都采用基于CAN-BUS网络的煤矿通讯网络。
附录 程序清单
CAN.ASM
MOD EQU 00H ;模式寄存器
CMR EQU 01H ;命令寄存器
SR EQU 02H ;状态寄存器
IR EQU 03H ;中断寄存器
IER EQU 04H ;中断使能寄存器
BTR0 EQU 06H ;总线定时寄存器0
BTR1 EQU 07H ;总线定时寄存器1
OCR EQU 08H ;输出控制寄存器
ALC EQU 0BH ;仲裁丢失捕捉寄存器
ECC EQU 0CH ;错误代码捕捉寄存器
TXERR EQU 0FH ;发送错误计数器
ACR0 EQU 10H ;验收代码寄存器0
ACR1 EQU 11H ;验收代码寄存器1
ACR2 EQU 12H ;验收代码寄存器2
ACR3 EQU 13H ;验收代码寄存器3
AMR0 EQU 14H ;验收屏蔽寄存器0
AMR1 EQU 15H ;验收屏蔽寄存器1
AMR2 EQU 16H ;验收屏蔽寄存器2
AMR3 EQU 17H ;验收屏蔽寄存器3
FIN EQU 10H ;发送/接收帧信息
ID1 EQU 11H ;发送/接收缓冲区之标示符一
ID2 EQU 12H ;发送/接收缓冲区之标示符二
DATA1 EQU 13H ;发送/接收数据首址
RBSA EQU 1EH ;接收缓冲器起始地址
CDR EQU 1FH ;时钟分频寄存器
;--------------- READER COS 1.0 --------------------------
ORG 4000H
JMP START
ORG 4080H
;--------------------------------主程序-----------------------------------
START: MOV DPH, #0D3H ;CAN1初始化(CAN1片选为
;LCS2:0D300H)
MOV R0, #0AAH ;验收代码为AAH
LCALL INITCAN
MOV DPH, #0D4H ;CAN2初始化(CAN2片选为
;LCS3:0D400H)
MOV R0, #0BBH ;验收代码为BBH
LCALL INITCAN
;-----------------------------------------------------------------
MOV R0, #20H ;20H-27H赋初值
MOV R1, #00H
MOV DPTR,#TXDATA
SS1: MOV A,R1
MOVC A, @A+DPTR
MOV @R0, A
INC R0
INC R1
CJNE R1,#08,SS1

;------------------------- CAN1发送1帧数据------------------
LOOP: MOV DPH, #0D3H
MOV R0, #20H
LCALL SEND ;发送20H为首址的1帧数据(前三
;控制字节为:08H、BBH、FFH，由程序给出）
LCALL DELAY ;调用延时子程序
;-------------------------CAN2接收1帧数据------------------------
MOV DPH, #0D4H
MOV R0, #30H
LCALL RECV ;调用接收数据子程序
NOP ;设断点处
HALT: JMP LOOP

TXDATA:DB 0AAH,0BBH,0CCH,0D4H ;要发送的一帧数据，用户可改写
DB 0E5H,0F6H,97H,18H
;----------------------------初始化子程序-------------------------------
INITCAN: ;DPH、R0为入口参数
MOV DPL,#MOD ;模式寄存器，选择单验收滤波器模
;式，进入复位模式
MOV A,#09H
MOVX @DPTR,A
MOV DPL,#CDR ;时钟分频器，选择PeliCAN模式，
MOV A,#88H ;关闭CLKOUT输出
MOVX @DPTR, A
MOV DPL,#IER ;中断使能寄存器，开溢出、错误、
MOV A,#0DH ;接收中断
MOVX @DPTR,A
MOV DPL,#BTR0 ;总线定时寄存器0
MOV A,#03H
MOVX @DPTR,A
MOV DPL,#BTR1 ;总线定时寄存器1，6MHz晶振，
MOV A,#0FFH ;波特率30Kbps
MOVX @DPTR,A
MOVX A, @DPTR
MOV DPL,#OCR ;输出控制寄存器，
;选择正常输出模式
MOV A,#0AAH
MOVX @DPTR,A
MOV DPL,#ACR0 ;验收代码寄存器ACR0
MOV A, R0
MOVX @DPTR,A
INC DPTR ;验收代码寄存器ACR1
MOV A,#0FFH
MOVX @DPTR,A
INC DPTR ;验收代码寄存器ACR2
MOVX @DPTR,A
INC DPTR ;验收代码寄存器ACR3
MOVX @DPTR,A
MOV DPL,#AMR0 ;验收屏蔽寄存器AMR0
MOV A,#00H
MOVX @DPTR,A
INC DPTR ;验收屏蔽寄存器AMR1
MOV A,#0FFH
MOVX @DPTR,A
INC DPTR ;验收屏蔽寄存器AMR2
MOVX @DPTR,A
INC DPTR ;验收屏蔽寄存器AMR3
MOVX @DPTR,A
MOV DPL, #RBSA ;接收缓冲器起始地址为0
MOV A, #00H
MOVX @DPTR, A
MOV DPL, #TXERR ;清除发送错误计数器
MOVX @DPTR, A
MOV DPL, #ECC ;清除错误代码捕捉寄存器
MOVX @DPTR, A
MOV DPL,#MOD ;单验收滤波器模式，返回工作模式
MOV A,#08H
MOVX @DPTR,A
RET
;--------------------------发送数据子程序------------------------
SEND: ;DPH、R0为入口参数
MOV DPL,#FIN ;SJA1000 发送缓存区首址
MOV A, #08H
MOVX @DPTR, A
INC DPL
MOV A, #0BBH
MOVX @DPTR, A
INC DPL
MOV A, #0FFH
MOVX @DPTR, A
INC DPL
MOV R2, #08H
SEND1: MOV A, @R0 ;R0为发送数据首址
MOVX @DPTR, A
INC R0
INC DPL
DJNZ R2, SEND1
MOV DPL,#CMR ;命令寄存器发出发送请求，
MOV A,#01H ;启动SJA1000 发送
MOVX @DPTR,A
RET
;-----------------------接收数据子程序--------------------
RECV: ;DPH、R0为入口参数
MOV DPL,#SR ;状态寄存器地址
MOVX A,@DPTR
ANL A, #0C3H ;读取总线关闭、出错、接收溢出、
;有数据等位
JNZ PROC
RET ;无上述状态，结束
PROC: JNB ACC.7, PROC1
BUSERR:MOV DPL, #IR ;IR中断寄存器，出现总线关闭
MOVX A, @DPTR ;读中断寄存器，清除中断位
MOV DPL, #MOD
MOV A, #08H
MOVX @DPTR, A ;将方式寄存器复位请求位清0
RET
NOP
PROC1: MOV DPL, #IR ;总线正常
MOVX A, @DPTR ;读取中断位
JNB ACC.3, OTHER
OVER: MOV DPL, #CMR ;数据溢出处理
MOV A, #0CH
MOVX @DPTR, A ;清除数据溢出位，释放接收缓冲区
RET
NOP
OTHER: JB ACC.0, RECE
LJMP RECOUT ;接收缓冲区无数据
NOP
RECE: MOV DPL, #FIN ;接收缓冲区有数据
MOVX A,@DPTR
JNB ACC.6, RDATA
MOV DPL, #CMR ;远程帧处理
MOV A, #04H
MOVX @DPTR, A
LJMP RECOUT
NOP
RDATA: MOV DPL, #FIN ;发送/接收数据首址
MOVX A, @DPTR
INC DPL
MOVX A, @DPTR
INC DPL
MOVX A, @DPTR
INC DPL
MOV R2, #08H
RDATA1: MOVX A, @DPTR
MOV @R0, A ;将接收数据传至R0为首址的内存中
INC DPL
INC R0
DJNZ R2, RDATA1
MOV DPL, #CMR
MOV A, #04H
MOVX @DPTR, A
RECOUT:MOV DPL, #ALC ;释放仲裁丢失捕捉寄存器
MOVX A, @DPTR
MOV DPL, #ECC ;释放错误代码捕捉寄存器
MOVX A, @DPTR
NOP
RET
;--------------------延时子程序---------------------
DELAY: MOV R2, #40
DELAY1: MOV R4, #255
DELAY2: NOP
DJNZ R4, DELAY2
DJNZ R2, DELAY1
RET
END

参考文献
[1] 李全利，迟荣强.单片机原理及接口技术.北京：高等教育出版社，2004
[2] 饶运涛，邹继军，郑勇芸.现场总线CAN原理与应用技术.北京：北京航空航天大学出版社，2003
[3] 邬宽明. CAN总线原理和应用系统设计. 北京：北京航空航天大学出版社，2004
[4] 杨金岩，郑应强，张振宇.8051单片机数据传输接口扩展技术与应用实例.北京：人民邮电出版社，2005
[5] 陈晓忠，黄宁，赵小侠.单片机接口技术适用子程序.北京：人民邮电出版社，2005
[6] 邬宽明. 单片机外围器件使用手册数据传输接口器件分册.北京：北京航空航天大学出版社，1998
[7] 广州周立功单片机发展有限公司. SJA1000独立CAN控制器应用指南
[8] 广州周立功单片机发展有限公司. PCA82C250 CAN控制器接口数据手册

17

参考：

毕业论文（设计）工作记录及成绩评定册

题 目：
学生姓名：
学 号：
专 业：
班 级：
指 导 教 师：
职称：
助理指导教师：
职称：

年 月 日
实验中心制

使 用 说 明

一、此册中各项内容为对学生毕业论文（设计）的工作和成绩评定记录，请各环节记录人用黑色或蓝色钢笔（签字笔）认真填写（建议填写前先写出相应草稿，以避免填错），并妥善保存。
二、此册于学院组织对各专业题目审查完成后，各教研室汇编选题指南，经学生自由选题后，由实验中心组织发给学生。
三、学生如实填好本册封面上的各项内容和选题审批表的相应内容，经指导教师和学院领导小组批准后，交指导教师；指导老师填好《毕业论文（设计）任务书》的各项内容，经教研室审核后交学生签名确认其毕业论文（设计）工作任务。
四、学生在指导老师的指导下填好《毕业论文（设计）开题报告》各项内容，由指导教师和教研室审核通过后，确定其开题，并将此册交指导老师保存。
五、指导老师原则上每周至少保证一次对学生的指导，如实按时填好《毕业论文（设计）指导教师工作记录》，并请学生签字确认。
六、中期检查时，指导老师将此册交学生填写前期工作小结，指导教师对其任务完成情况进行评价，学院中期检查领导小组对师生中期工作进行核查，并对未完成者提出整改意见，后将此册交指导老师保存。
七、毕业论文（设计）定稿后，根据学院工作安排，学生把论文（打印件）交指导老师评阅。指导老师应认真按《毕业论文（设计）指导教师成绩评审表》对学生的论文进行评审并写出评语，然后把论文和此册一同交教研室。
八、教研室将学生的论文和此册分别交两位评阅人评阅后交回教研室保存。
九、学院答辩委员会审核学生答辩资格，确定答辩学生名单，把具有答辩资格学生的论文连同此册交各答辩小组。
十、学生答辩后由答辩小组记录人填好《毕业论文（设计）答辩记录表》中各项内容，然后把学生的论文和此册一同交所在答辩小组，答辩小组对其答辩进行评审并填写评语后交教研室。
十一、学院答辩委员会进行成绩总评定，填好《毕业论文（设计）成绩评定表》中各项内容，然后把论文（印刷版和电子版（另传））和此册等资料装入专用档案袋中，教教研室后由实验中心统一保存。

目 录

1．毕业论文（设计）选题审批表
2. 毕业论文（设计）任务书
3．毕业论文（设计）开题报告
4. 学生毕业论文（设计）题目更改申请表
5．毕业论文（设计）指导老师工作记录
6．毕业论文（设计）中期检查记录
7．毕业论文（设计）指导教师成绩评审表
8．毕业论文（设计）评阅人成绩评审表
9. 毕业论文（设计）答辩申请表
10．毕业论文（设计）答辩记录表
11．毕业论文（设计）答辩成绩评审表
12．毕业论文（设计）成绩评定表

毕业设计（论文）选题审批表
题目名称
基于单片机的超声波测距
题目性质
□工程设计　　□理论研究
□实验研究　　□计算机软件
□综合论文　　□其它
题目来源
□科研题目 　□生产现场
□教学　 　□其它
□自拟题目
选题理由：由于超声波指向性强，能量消耗缓慢，在介质中传播的距离较远，因而超声波
经常用于距离的测量。利用超声波检测距离，设计比较方便，计算处理也较简单，精度也能达到使用要求，超声波测距应用于各种工业领域，如工业自动控制，建筑工程测量和机器人视觉识别等方面。超声波作为一种检测技术，采用的是非接触式测量，由于它具有不受外界因素影响，对环境有一定的适应能力，且操作简单、测量精度高等优点而被广泛应用。这些特点可使测量仪器不受被测介质的影响，大大解决了传统测量仪器存在的问题，比如，在粉尘多情况下对人引起的身体接触伤害，腐蚀性质的被测物对测量仪器腐蚀，触电接触不良造成的误测等。此外该技术对被测元件无磨损，使测量仪器牢固耐用，使用寿命加长，而且还降低了能量耗损，节省人力和劳动的强度。因此，利用超声波检测既迅速、方便、计算简单，又易于实时控制，在测量精度方面能达到工业实用的要求。

指导教师意见：

签名：