80X86微机原理及接口技术实验教程.doc

80X86微机原理及接口技术

实验教程

80X86微机原理及接口技术实验教程
目 录
目 录 1
第1章 16位微机原理及其程序设计实验 2
1.1 系统认识实验 2
1.2 数制转换实验 9
1.3 运算类编程实验 18
1.4 分支程序设计实验 24
1.5 循环程序设计实验 28
1.6 排序程序设计实验 31
1.7 子程序设计实验 35
1.8 查表程序设计实验 40
第2章 80X86微机接口技术及其应用实验 42
2.1 静态存储器扩展实验 42
2.2 8259中断控制实验 46
2.3 8254定时/计数器应用实验 56
2.4 8255并行接口实验 63
2.5 8251串行接口应用实验 69
2.6 实时时钟综合设计实验 84
2.7 键盘扫描及显示设计实验 86
2.8 电子发声设计实验 92
2.9 点阵LED显示设计实验 98
2.10 图形LCD显示设计实验 107
2.11 步进电机实验 116
2.12 直流电机闭环调速实验 120
2.13 温度闭环控制实验 131

1

第1章 16位微机原理及其程序设计实验
本章主要介绍汇编语言程序设计，通过实验来学习80X86的指令系统、寻址方式以及程序的设计方法，同时掌握联机软件的使用。

1.1 系统认识实验
1.1.1 实验目的
掌握TD系列微机原理及接口技术教学实验系统的操作，熟悉Wmd86联机集成开发调试软件的操作环境。
1.1.2 实验设备
PC机一台，TD-PITE实验装置一套。
1.1.3 实验内容
编写实验程序，将00H～0FH共16个数写入内存3000H开始的连续16个存储单元中。
1.1.4 实验步骤
1. 运行Wmd86软件，进入Wmd86集成开发环境。
2. 根据程序设计使用语言的不同，通过在“设置”下拉列表来选择需要使用的语言和寄存器类型，这里我们设置成“汇编语言”和“16位寄存器”，如图1.1、图1.2所示。设置选择后，下次再启动软件，语言环境保持这次的修改不变。本章选择16位寄存器。

图1.1 语言环境设置界面

图1.2 寄存器设置界面

3. 语言和寄存器选择后，点击新建或按Ctrl+N组合键来新建一个文档，如图1.3所示。默认文件名为Wmd861。

图1.3 新建文件界面

4. 编写实验程序，如图1.4所示，并保存，此时系统会提示输入新的文件名，输完后点击保存。

图1.4 程序编辑界面
5. 点击，编译文件，若程序编译无误，则可以继续点击进行链接，链接无误后方可以加载程序。编译、链接后输出如图1.5所示的输出信息。

图1.5 编译输出信息界面

6. 连接PC与实验系统的通讯电缆，打开实验系统电源。
7. 编译、链接都正确并且上下位机通讯成功后，就可以下载程序，联机调试了。可以通过端口列表中的“端口测试”来检查通讯是否正常。点击下载程序。为编译、链接、下载组合按钮，通过该按钮可以将编译、链接、下载一次完成。下载成功后，在输出区的结果窗中会显示“加载成功！”，表示程序已正确下载。起始运行语句下会有一条绿色的背景。如图1.6所示。

图1.6 加载成功显示界面

8. 将输出区切换到调试窗口，使用D0000:3000命令查看内存3000H起始地址的数据，如图1.7所示。存储器在初始状态时，默认数据为CC。

图1.7 内存地址单元数据显示

9. 点击按钮运行程序，待程序运行停止后，通过D0000:3000命令来观察程序运行结果。如图1.8所示。

图1.8 运行程序后数据变化显示
10. 也可以通过设置断点，断点显示如图1.9所示，然后运行程序，当遇到断点时程序会停下来，然后观察数据。可以使用E0000:3000来改变该地址单元的数据，如图1.10所示，输入11后，按“空格”键，可以接着输入第二个数，如22，结束输入按“回车”键。

图1.9 断点设置显示 图1.10 修改内存单元数据显示界面

实验例程文件名为Wmd861.asm。
1.1.5 操作练习
编写程序，将内存3500H单元开始的8个数据复制到3600H单元开始的数据区中。通过调试验证程序功能，使用E命令修改3500H单元开始的数据，运行程序后使用D命令查看3600H单元开始的数据。

1.2 数制转换实验
1.2.1 实验目的
1. 掌握不同进制数及编码相互转换的程序设计方法，加深对数制转换的理解。
2. 熟悉程序调试的方法。
1.2.2 实验设备
PC机一台，TD-PITE实验装置一套。
1.2.3 实验内容及步骤
计算机输入设备输入的信息一般是由ASCII码或BCD码表示的数据或字符，CPU一般均用二进制数进行计算或其它信息处理，处理结果的输出又必须依照外设的要求变为ASCII码、BCD码或七段显示码等。因此，在应用软件中，各类数制的转换是必不可少的。
计算机与外设间的数制转换关系如图1.11所示，数制对应关系如表1.1所示。

图1.11 数制转换关系

1. 将ASCII码表示的十进制数转换为二进制数
十进制表示为：
（1）
Di代表十进制数0，1，2，…，9；
上式转换为：
（2）
由式（2）可归纳十进制数转换为二进制数的方法：从十进制数的最高位Dn开始作乘10加次位的操作，依次类推，则可求出二进制数的结果。
表1.1 数制对应关系表
十六进制
BCD码
二进制
机器码
ASCII码
七段码
共阳
共阴
0
0000
0000
30H
40H
3FH
1
0001
0001
31H
79H
06H
2
0010
0010
32H
24H
5BH
3
0011
0011
33H
30H
4FH
4
0100
0100
34H
19H
66H
5
0101
0101
35H
12H
6DH
6
0110
0110
36H
02H
7DH
7
0111
0111
37H
78H
07H
8
1000
1000
38H
00H
7FH
9
1001
1001
39H
18H
67H
A

1010
41H
08H
77H
B

1011
42H
03H
7CH
C

1100
43H
46H
39H
D

1101
44H
21H
5EH
E

1110
45H
06H
79H
F

1111
46H
0EH
71H

程序流程图如图1.12所示。实验参考程序如下。
实验程序清单（例程文件名：A2-1.ASM）
SSTACK SEGMENT STACK
DW 64 DUP(?)
SSTACK ENDS
DATA SEGMENT
SADD DB 30H,30H,32H,35H,36H ;十进制数:00256
DATA ENDS
CODE SEGMENT
ASSUME CS:CODE, DS:DATA
START: MOV AX, DATA
MOV DS, AX
MOV AX, OFFSET SADD
MOV SI, AX
MOV BX, 000AH
MOV CX, 0004H
MOV AH, 00H
MOV AL, [SI]
SUB AL, 30H
A1: IMUL BX
MOV DX, [SI+01]
AND DX, 00FFH
ADC AX, DX
SBB AX, 30H
INC SI
LOOP A1
A2: JMP A2
CODE ENDS
END START
实验步骤
（1）绘制程序流程图，编写实验程序，经编译、链接无误后装入系统。
（2）待转换数据存放于数据段，根据自己要求输入，默认为30H，30H，32H，35H，36H。
（3）运行程序，然后停止程序。
（4）查看AX寄存器，即为转换结果，应为：0100 。
（5）反复试几组数据，验证程序的正确性。
2. 将十进制数的ASCII码转换为BCD码
从键盘输入五位十进制数的ASCII码，存放于3500H起始的内存单元中，将其转换为BCD码后，再按位分别存入350AH起始的内存单元内。若输入的不是十进制的ASCII码，则对应存放结果的单元内容为“FF”。由表1.1可知，一字节ASCII码取其低四位即变为BCD码。
实验程序清单（例程文件名：A2-2.ASM）
SSTACK SEGMENT STACK
DW 64 DUP(?)
SSTACK ENDS 图1.12 转换程序流程图
CODE SEGMENT
ASSUME CS:CODE
START: MOV CX, 0005H ;转换位数
MOV DI, 3500H ;ASCII码首地址
A1: MOV BL, 0FFH ;将错误标志存入BL
MOV AL, [DI]
CMP AL, 3AH
JNB A2 ;不低于3AH则转A2
SUB AL, 30H
JB A2 ;低于30H则转A2
MOV BL, AL
A2: MOV AL, BL ;结果或错误标志送入AL
MOV [DI+0AH],AL ;结果存入目标地址
INC DI
LOOP A1
MOV AX,4C00H
INT 21H ;程序终止
CODE ENDS
END START
实验步骤
（1）自己绘制程序流程图，然后编写程序，编译、链接无误后装入系统。
（2）在3500H～3504H单元中存放五位十进制数的ASCII码，即：键入E3500后，输入31，32，33，34，35。
（3）运行程序，待程序运行停止。
（4）在调试窗口键入D350A，显示运行结果，应为：
0000:350A 01 02 03 04 05 CC …
（5）反复测试几组数据，验证程序功能。
3. 将十六位二进制数转换为ASCII码表示的十进制数
十六位二进制数的值域为0～65535，最大可转换为五位十进制数。
五位十进制数可表示为：

Di：表示十进制数0～9
将十六位二进制数转换为五位ASCII码表示的十进制数，就是求D1～D4，并将它们转换为ASCII码。自行绘制程序流程图，编写程序可参考例程。例程中源数存放于3500H、3501H中，转换结果存放于3510H～3514H单元中。
实验程序清单（例程文件名：A2-3.ASM）
SSTACK SEGMENT STACK
DW 64 DUP(?)
SSTACK ENDS
CODE SEGMENT
ASSUME CS:CODE
START: MOV SI,3500H ;源数据地址
MOV DX,[SI]
MOV SI,3515H ;目标数据地址
A1: DEC SI
MOV AX,DX
MOV DX,0000H
MOV CX,000AH ;除数10
DIV CX ;得商送AX, 得余数送DX
XCHG AX,DX
ADD AL,30H ;得Di的ASCII码
MOV [SI],AL ;存入目标地址
CMP DX,0000H
JNE A1 ;判断转换结束否，未结束则转A1
A2: CMP SI,3510H ;与目标地址得首地址比较
JZ A3 ;等于首地址则转A3，否则将剩余地址中填30H
DEC SI
MOV AL,30H
MOV [SI],AL
JMP A2
A3: MOV AX,4C00H
INT 21H ;程序终止
CODE ENDS
END START
实验步骤
（1）编写程序，经编译、链接无误后，装入系统。
（2）在3500H、3501H中存入0C 00。
（3）运行程序，待程序运行停止。
（4）检查运行结果，键入D3510，结果应为：30 30 30 31 32。
（5）可反复测试几组数据，验证程序的正确性。
4. 十六进制数转换为ASCII码
由表1.1中十六进制数与ASCII码的对应关系可知：将十六进制数0H～09H加上30H后得到相应的ASCII码，AH～FH加上37H可得到相应的ASCII码。将四位十六进制数存放于起始地址为3500H的内存单元中，把它们转换为ASCII码后存入起始地址为350AH的内存单元中。自行绘制流程图。
实验程序清单（例程文件名为A2-4.ASM）
SSTACK SEGMENT STACK
DW 64 DUP(?)
SSTACK ENDS
CODE SEGMENT
ASSUME CS:CODE
START: MOV CX,0004H
MOV DI,3500H ;十六进制数源地址
MOV DX,[DI]
A1: MOV AX,DX
AND AX,000FH ;取低4位
CMP AL,0AH
JB A2 ;小于0AH则转A2
ADD AL,07H ;在A～FH之间，需多加上7H
A2: ADD AL,30H ;转换为相应ASCII码
MOV [DI+0DH],AL ;结果存入目标地址
DEC DI
PUSH CX
MOV CL,04H
SHR DX,CL ;将十六进制数右移4位
POP CX
LOOP A1
MOV AX,4C00H
INT 21H ;程序终止
CODE ENDS
END START
实验步骤
（1）编写程序，经编译、链接无误后装入系统。
（2）在3500H、3501H中存入四位十六进制数203B，即键入E3500，然后输入3B 20。
（3）先运行程序，待程序运行停止。
（4）键入D350A，显示结果为：0000:350A 32 30 33 42 CC …。
（5）反复输入几组数据，验证程序功能。
5. BCD码转换为二进制数
将四个二位十进制数的BCD码存放于3500H起始的内存单元中，将转换的二进制数存入3510H起始的内存单元中，自行绘制流程图并编写程序。
实验程序清单（例程文件名为：A2-5.ASM）
SSTACK SEGMENT STACK
DW 64 DUP(?)
SSTACK ENDS
CODE SEGMENT
ASSUME CS:CODE
START: XOR AX, AX
MOV CX, 0004H
MOV SI, 3500H
MOV DI, 3510H
A1: MOV AL, [SI]
ADD AL, AL
MOV BL, AL
ADD AL, AL
ADD AL, AL
ADD AL, BL
INC SI
ADD AL, [SI]
MOV [DI], AL
INC SI
INC DI
LOOP A1
MOV AX,4C00H
INT 21H ;程序终止
CODE ENDS
END START
实验步骤
（1）编写程序，经编译、链接无误后装入系统。
（2）将四个二位十进制数的BCD码存入3500H～3507H中，即：
先键入E3500，然后输入01 02 03 04 05 06 07 08。
（3）先运行程序，待程序运行停止。
（4）键入D3510显示转换结果，应为：0C 22 38 4E。
（5）反复输入几组数据，验证程序功能。
1.2.4 思考题
1. 实验内容1中将一个五位十进制数转换为二进制数（十六位）时，这个十进制数最小可为多少，最大可为多少？为什么？
2. 将一个十六位二进制数转换为ASCII码十进制数时，如何确定Di的值？
3. 在十六进制转换为ASCII码时，存转换结果后，为什么要把DX向右移四次？
4. 自编ASCII码转换十六进制、二进制转换BCD码的程序，并调试运行。

1.3 运算类编程实验
1.3.1 实验目的
1. 掌握使用运算类指令编程及调试方法。
2. 掌握运算类指令对各状态标志位的影响及其测试方法。
3. 学习使用软件监视变量的方法。
1.3.2 实验设备
PC机一台，TD-PITE实验装置一套。
1.3.3 实验内容及步骤
80X86指令系统提供了实现加、减、乘、除运算的基本指令，可对表1.2所示的数据类型进行算术运算。
表1.2 数据类型算术运算表
数制
二进制
BCD码
带符号
无符号
组合
非组合
运算符
＋、－、×、÷
＋、－
＋、－、×、÷
操作数
字节、字、多精度
字节（二位数字）
字节（一位数字）

1. 二进制双精度加法运算
计算X＋Y＝Z，将结果Z存入某存储单元。实验程序参考如下。
本实验是双精度（2个16位，即32位）加法运算，编程时可利用累加器AX，先求低16位的和，并将运算结果存入低地址存储单元，然后求高16位的和，将结果存入高地址存储单元中。由于低16运算后可能向高位产生进位，因此高16位运算时使用ADC指令，这样在低16位相加运算有进位时，高位相加会加上CF中的1。
实验程序清单（例程文件名为：A3-1.ASM）
SSTACK SEGMENT STACK
DW 64 DUP(?)
SSTACK ENDS
PUBLIC XH, XL, YH, YL, ZH, ZL ;设置全局变量
DATA SEGMENT
XL DW ? ;X低位
XH DW ? ;X高位
YL DW ? ;Y低位
YH DW ? ;Y高位
ZL DW ? ;Z低位
ZH DW ? ;Z高位
DATA ENDS
CODE SEGMENT
ASSUME CS:CODE, DS:DATA
START: MOV AX, DATA
MOV DS, AX
MOV AX, XL
ADD AX, YL ;X低位加Y低位
MOV ZL, AX ;低位和存到Z的低位
MOV AX, XH
ADC AX, YH ;高位带进位加
MOV ZH, AX ;存高位结果
JMP START ;在此行设置断点，以观察变量值
CODE ENDS
END START
实验步骤
（1）编写程序，经编译、链接无误后装入系统。
（2）程序装载完成后，点击‘变量区’标签将观察窗切换到变量监视窗口。
（3）点击，将变量XH，XL，YH，YL，ZH，ZL添加到变量监视窗中，然后修改XH，XL，YH，YL的值，如图2.13所示，修改XH为0015，XL为65A0，YH为0021，YL为B79E。
（4）在JMP START语句行设置断点，然后运行程序。
（5）当程序遇到断点后停止运行，查看变量监视窗口，计算结果ZH为0037，ZL为1D3E。
（6）修改XH，XL，YH和YL的值，再次运行程序，观察实验结果，反复测试几组数据，验证程序的功能。
思考题：
①. 求累加和程序设计，在偏移地址为1000H开始依顺序填入16个字（16个16位数），利用程序求和，存放在偏移地址2000H;
②. 多字节加法程序设计，参考原程序，编写个两个64位数的减法程序，结果保存到具体内存单元，调试并记录。
图1.13 变量监视窗口
2. 十进制的BCD码减法运算
计算X－Y＝Z，其中X、Y、Z为BCD码。实验程序参考例程。
实验程序清单（例程文件名为A3-2.ASM）
SSTACK SEGMENT STACK
DW 64 DUP(?)
SSTACK ENDS
PUBLIC X, Y, Z ;定义全局变量
DATA SEGMENT
X DW ?
Y DW ?
Z DW ?
DATA ENDS
CODE SEGMENT
ASSUME CS:CODE, DS:DATA
START: MOV AX, DATA
MOV DS, AX
MOV AH, 00H
SAHF
MOV CX, 0002H
MOV SI, OFFSET X
MOV DI, OFFSET Z
A1: MOV AL, [SI]
SBB AL, [SI+02H]
DAS
PUSHF
AND AL, 0FH
POPF
MOV [DI], AL
INC DI
INC SI
LOOP A1
JMP START ;设置断点，以方便观察变量。
CODE ENDS
END START
实验步骤
（1）输入程序，编译、链接无误后装入系统。
（2）点击将变量X，Y，Z添加到变量监视窗中，并为X，Y赋值，假定存入40与12的BCD码，即X为0400，Y为0102。
（3）在JMP START语句行设置断点，然后运行程序。
（4）程序遇到断点后停止运行，观察变量监视窗，Z应为0208。
（5）重新修改X与Y的值，运行程序，观察结果，反复测试几次，验证程序正确性。

3. 乘法运算
实现十进制数的乘法运算，被乘数与乘数均以BCD码的形式存放在内存中，乘数为1位，被乘数为5位，结果为6位。实验程序参考例程。
实验程序清单（例程文件名为A3-3.ASM）
SSTACK SEGMENT STACK
DW 64 DUP(?)
SSTACK ENDS
DATA SEGMENT
DATA1 DB 5 DUP(?) ;被乘数
DATA2 DB ? ;乘数
RESULT DB 6 DUP(?) ;计算结果
DATA ENDS
CODE SEGMENT
ASSUME CS:CODE,DS:DATA
START: MOV AX,DATA
MOV DS,AX
CALL INIT ;初始化目标地址单元为0
MOV SI,OFFSET DATA2
MOV BL,[SI]
AND BL,0FH ;得到乘数
CMP BL,09H
JNC ERROR
MOV SI,OFFSET DATA1
MOV DI,OFFSET RESULT
MOV CX,0005H
A1: MOV AL,[SI+04H]
AND AL,0FH
CMP AL,09H
JNC ERROR
DEC SI
MUL BL
AAM ;乘法调整指令
ADD AL,[DI+05H]
AAA
MOV [DI+05H],AL
DEC DI
MOV [DI+05H],AH
LOOP A1
A2: MOV AX,4C00H
INT 21H ;程序终止
;===将RESULT所指内存单元清零===
INIT: MOV SI,OFFSET RESULT
MOV CX,0003H
MOV AX,0000H
A3: MOV [SI],AX
INC SI
INC SI
LOOP A3
RET
;===错误处理===
ERROR: MOV SI,OFFSET RESULT ;若输入数据不符合要求则RESULT所指向内存单元全部写入E
MOV CX,0003H
MOV AX,0EEEEH
A4: MOV [SI],AX
INC SI
INC SI
LOOP A4
JMP A2
CODE ENDS
END START

实验步骤
（1）编写程序，编译、链接无误后装入系统。
（2）查看寄存器窗口获得CS的值，使用U命令可得到数据段段地址DS，然后通过E命令为被乘数及乘数赋值，如被乘数：01 02 03 04 05，乘数：01，方法同实验内容1。
（3）运行程序，待程序运行停止。
（4）通过D命令查看计算结果，应为：00 01 02 03 04 05；当在为被乘数和乘数赋值时，如果一个数的低4位大于9，则查看计算结果将全部显示为E。
（5）反复测试几组数据，验证程序的正确性。

1.4 分支程序设计实验
1.4.1 实验目的
1. 掌握分支程序的结构。
2. 掌握分支程序的设计、调试方法。
1.4.2 实验设备
PC机一台，TD-PITE实验装置一套。
1.4.3 实验内容
设计一数据块间的搬移程序。设计思想：程序要求把内存中一数据区（称为源数据块）传送到另一存储区（成为目的数据块）。源数据块和目的数据块在存储中可能有三种情况，如图1.14所示。

（a） （b） （c）
图1.14 源数据块与目的数据块在存储中的位置情况
对于两个数据块分离的情况，如图1.14（a），数据的传送从数据块的首地址开始，或从数据块的末地址开始均可。但是对于有重叠的情况，则要加以分析，否则重叠部分会因“搬移”而遭到破坏，可有如下结论：
当源数据块首地址＜目的块首地址时，从数据块末地址开始传送数据，如图1.14（b）所示。
当源数据块首地址＞目的块首地址时，从数据块首地址开始传送数据，如图1.14（c）所示。
实验程序流程图如图1.15所示。

图1.15 程序流程图

实验程序清单（例程文件名为：A4-1.ASM）
SSTACK SEGMENT STACK
DW 64 DUP(?)
SSTACK ENDS
CODE SEGMENT
ASSUME CS:CODE
START: MOV CX, 0010H
MOV SI, 3100H
MOV DI, 3200H
CMP SI, DI
JA A2
ADD SI, CX
ADD DI, CX
DEC SI
DEC DI
A1: MOV AL, [SI]
MOV [DI], AL
DEC SI
DEC DI
DEC CX
JNE A1
JMP A3
A2: MOV AL, [SI]
MOV [DI], AL
INC SI
INC DI
DEC CX
JNE A2
A3: MOV AX,4C00H
INT 21H ;程序终止
CODE ENDS
END START
1.4.4 实验步骤
1. 按流程图编写实验程序，经编译、链接无误后装入系统。
2. 用E命令在以SI为起始地址的单元中填入16个数。
3. 运行程序，待程序运行停止。
4. 通过D命令查看DI为起始地址的单元中的数据是否与SI单元中数据相同。
5. 通过改变SI、DI的值，观察在三种不同的数据块情况下程序的运行情况，并验证程序的功能。
思考题：
将源数据首址改为3100H,目的数据地址改为310A，再加以验证（注意单步调试）；
将源数据首址改为310AH,目的数据地址改为3100，再加以验证（注意单步调试）。

1.5 循环程序设计实验
1.5.1 实验目的
1. 加深对循环结构的理解。
2. 掌握循环结构程序设计的方法以及调试方法。
1.5.2 实验设备
PC机一台，TD-PITE实验装置一套。
1.5.3 实验内容及步骤
1. 计算S＝1＋2×3＋3×4＋4×5＋…＋N（N＋1），直到N（N＋1）项大于200为止。
编写实验程序，计算上式的结果，参考流程图如图1.16所示。
实验程序清单（例程文件名为：A5-1.ASM）
SSTACK SEGMENT STACK
DW 64 DUP(?)
SSTACK ENDS
CODE SEGMENT
ASSUME CS:CODE
START: MOV DX,0001H
MOV BL,02H
A1: MOV AL,BL
INC BL
MUL BL
ADD DX,AX ;结果存于DX中
CMP AX,00C8H ;判断N(N+1)与200的大小
JNA A1
MOV AX,4C00H
INT 21H ;程序终止
CODE ENDS
END START

实验步骤
（1）编写实验程序，编译、链接无误后装入系统。 图1.16 程序流程图
（2）运行程序，待程序运行停止。
（3）运算结果存储在寄存器DX中，查看结果是否正确。
（4）可以改变N（N＋1）的条件来验证程序功能是否正确，但要注意，结果若大于0FFFFH将产生数据溢出。

2. 求某数据区内负数的个数
设数据区的第一单元存放区内单元数据的个数，从第二单元开始存放数据，在区内最后一个单元存放结果。为统计数据区内负数的个数，需要逐个判断区内的每一个数据，然后将所有数据中凡是符号位为1的数据的个数累加起来，即得到区内所包含负数的个数。
实验程序流程图如图1.17所示。
实验程序清单（例程文件名为：A5-2.ASM）
SSTACK SEGMENT STACK
DW 64 DUP(?)
SSTACK ENDS
CODE SEGMENT
ASSUME CS:CODE
START: MOV DI, 3000H ;数据区首地址
MOV CL, [DI] ;取数据个数
XOR CH, CH
MOV BL, CH
INC DI ;指向第一个数据
A1: MOV AL, [DI]
TEST AL, 80H ;检查数据首位是否为1
JE A2
INC BL ;负数个数加1
A2: INC DI
LOOP A1
MOV [DI], BL ;保存结果
MOV AX,4C00H
INT 21H ;程序终止
CODE ENDS
END START
实验步骤
（1）按实验流程编写实验程序。
（2）编译、链接无误后装入系统。
（3）键入E3000，输入数据如下：
3000＝06 （数据个数）
3001＝12
3002＝88
3003＝82
3004＝90
3005＝22
3006＝33 图1.17 程序流程图
（4）先运行程序，待程序运行停止。
（5）查看3007内存单元或寄存器BL中的内容，结果应为03。
（6）可以进行反复测试来验证程序的正确性。

1.6 排序程序设计实验
1.6.1 实验目的
1. 掌握分支、循环、子程序调用等基本的程序结构。
2. 学习综合程序的设计、编制及调试。
1.6.2 实验设备
PC机一台，TD-PITE实验装置一套。
1.6.3 实验内容及步骤
1. 气泡排序法
在数据区中存放着一组数，数据的个数就是数据缓冲区的长度，要求采用气泡法对该数据区中的数据按递增关系排序。
设计思想：
（1）从最后一个数（或第一个数）开始，依次把相邻的两个数进行比较，即第N个数与第N－1个数比较，第N－1个数与第N－2个数比较等等；若第N－1个数大于第N个数，则两者交换，否则不交换，直到N个数的相邻两个数都比较完为止。此时，N个数中的最小数将被排在N个数的最前列。
（2）对剩下的N－1个数重复（1）这一步，找到N－1个数中的最小数。
（3）再重复（2），直到N个数全部排列好为止。
实验程序清单（例程文件名为：A6-1.ASM）
SSTACK SEGMENT STACK
DW 64 DUP(?)
SSTACK ENDS
CODE SEGMENT
ASSUME CS:CODE
START: MOV CX, 000AH
MOV SI, 300AH
MOV BL, 0FFH
A1: CMP BL, 0FFH
JNZ A4
MOV BL, 00H
DEC CX
JZ A4
PUSH SI
PUSH CX
A2: DEC SI
MOV AL, [SI]
DEC SI
CMP AL, [SI]
JA A3
XCHG AL, [SI]
MOV [SI+01H], AL
MOV BL, 0FFH
A3: INC SI
LOOP A2
POP CX
POP SI
JMP A1
A4: MOV AX,4C00H
INT 21H ;程序终止
CODE ENDS
END START
实验步骤
（1）分析参考程序，绘制流程图并编写实验程序。
（2）编译、链接无误后装入系统。
（3）键入E3000命令修改3000H～3009H单元中的数，任意存入10个无符号数。
（4）先运行程序，待程序运行停止。
（5）通过键入D3000命令查看程序运行的结果。
（6）可以反复测试几组数据，观察结果，验证程序的正确性。
思考题：
注意两个循环是如何循环的，如果想减少判断次数，比如说几次交换后就不再有数据交换了，如何修改程序来减少程序执行时间；
编一程序把3000H-3009H中内容按从大到小排列；
如果是有符号数怎么改写程序。

2. 学生成绩名次表
将分数在1～100之间的10个成绩存入首地址为3000H的单元中，3000H＋I表示学号为I的学生成绩。编写程序，将排出的名次表放在3100H开始的数据区，3100H＋I中存放的为学号为I的学生名次。
实验程序清单（例程文件名为：A6-2.ASM）
SSTACK SEGMENT STACK
DW 64 DUP(?)
SSTACK ENDS
CODE SEGMENT
ASSUME CS:CODE
START: MOV AX,0000H
MOV DS,AX
MOV ES,AX
MOV SI,3000H ;存